Konu Araçları | Seçenekler: | Gösterim Stili
Tarih
17/07/2009 20:32
Konu Sahibi
mehmeser
Yorumlar
2
Okunma
1583
Konuyu Oyla:
  • Derecelendirme: 0/5 - 0 oy
  • 5
  • 4
  • 3
  • 2
  • 1

Derecelendirme: 0/5 - 0 oy
Kullanici Avatari

mehmeser

Aktif Üye
Aktif Üye
 135
 26
 07/02/2009
5
 -
 
 Ofis 2003
 17/01/2018,17:40
Information 
Aşağıdaki kod ile VT'deki tüm formların araç çubukları değiştirebilirsiniz. En iyisi her VT için yönetim paneli oluşturulması.

PHP Kod:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
Public Sub SetFormToolbars()
Dim objFrm As AccessObject, frm As Form, ctl As Control
    ' Go through every form in the database
    For Each objFrm In CurrentProject.AllForms
        ' Skip fixing any "plain" examples
        If Right(objFrm.Name, 5) <> "plain" Then
            DoCmd.OpenForm FormName:=objFrm.Name, View:=acDesign, WindowMode:=acHidden
            ' Set a pointer to the form just opened
            Set frm = Forms(objFrm.Name)
            ' Set custom menu and toolbars for the form object
            ' .. only for primary forms
            If Left(frm.Name, 3) = "frm" Then
                ' Clear any saved filter while we're at it
                Forms(frm.Name).Filter = ""
                ' Set the custom menu bar
                Forms(frm.Name).MenuBar = "FormMenuBar"
                ' Set the custom toolbar
                Forms(frm.Name).Toolbar = "FormToolbox"
                ' Set the custom shortcut menu bar
                Forms(frm.Name).ShortcutMenuBar = ""
            End If
            ' Loop through all controls
            For Each ctl In frm.Controls
                ' Skip control types that don't have a ShortcutMenuBar property
                If (ctl.ControlType <> acCustomControl) And _
                    (ctl.ControlType <> acSubform) And _
                    (ctl.ControlType <> acRectangle) And _
                    (ctl.ControlType <> acLabel) And _
                    (ctl.ControlType <> acLine) And _
                    (ctl.ControlType <> acPageBreak) Then
                    ' Set the custom control shortcut menu
                    ctl.ShortcutMenuBar = ""
                End If
            ' Loop through all controls on the form
            Next ctl
            ' Fix AllowDesignChanges while we're at it
            frm.AllowDesignChanges = False
            ' Close and save the result
            DoCmd.Close acForm, objFrm.Name, acSaveYes
        End If
    ' Loop to get the next form
    Next objFrm
    ' Clean up
    Set ctl = Nothing
    Set frm = Nothing
    Set objFrm = Nothing
End Sub



Burdaki kod plain'le başlayan formları es geçer, uyarlamayı unutmayınız.



Kullanici Avatari

remi

Aktif Üye
Aktif Üye
 49
 69
 3
 09/11/2008
0
 İstanbul
 
 Ofis 2003
 09/05/2018,10:51
Sayın mehmeser
Kodların nerde kullanıldığını anlıyamadım mümkünse bir örnek koyabilirmisinisiz.

Saygılarımla



Kullanici Avatari

mehmeser

Aktif Üye
Aktif Üye
 135
 26
 07/02/2009
5
 -
 
 Ofis 2003
 17/01/2018,17:40
Kodu bir modül-e ekleyin. Daha sonra form oluşturup üzerine komut düğmesi ekleyin. Düğmenin click olayına da (Call SetFormToolbars) komutunu ekleyin.

Kullanırken ya kod içinde istediğiniz araç çubuklarını ekleyeceksiniz ya da kodu parametreli şekilde ayarlayıp form üzerinden değerleri göndereceksiniz.

Eğer sürekli araç çubuğu değiştiriyorsanız tavsiye ederim. Dağıtım için hazırlık için güzel bir kod fakat her zaman lazım olmaz. Ama lazım olunca da keyfe keyif katar.




Konuyu Okuyanlar: 1 Ziyaretçi

Konu ile Alakalı Benzer Konular
Konular Yazar Yorumlar Okunma Son Yorum
Brick Kapsamlı Örnek. (kamu Kurumunda Araç Görevlendirme) istemihan 7 383 17/09/2018, 14:19
Son Yorum: Kılıçarslan
  Access Icon Değiştirme oosmaner 1 136 20/08/2018, 13:35
Son Yorum: ozanakkaya
Star Ziyaretçi - Araç Kayıt/Takip ve Tel. Rehberi Programi (Final) SCavusoglu 10 8.202 15/04/2018, 08:35
Son Yorum: alpergumus
  form üzerindeki metin kutusunun boyutunu otomatik ayarlama mehmetdemiral 7 4.939 08/04/2018, 20:58
Son Yorum: Mali06
  Listbox Veri Kaynağını Değiştirme Örnek. A.Kadir. 1 423 16/03/2018, 16:33
Son Yorum: ozanakkaya

Türkçe Çeviri: MCTR, Yazılım: MyBB, © 2002-2018 MyBB Group.